Using WM_COPYDATA with Delphi-Prism applications

Question

Does anyone have a good delphi-prism example of receiving and interpreting a WM_COPYDATA message? I'm particularly interested in how to deal with the message data structure.

Answer 1

Warren, the key for decoding the message, depends how you define your COPYDATASTRUCT record in the sender and receiver applications and use the GetLParam function.

check this code

//the sender application, this is a simple console app
namespace ConsoleApplication_PrismSendData;

interface
uses
    System.Runtime.InteropServices;
type
  [StructLayout(LayoutKind.Sequential)]
  CopyDataStruct = public record //the record to be passed by the WM_COPYDATA message. 
  public
    var     dwData: IntPtr;
    var     cbData: System.Int32;
    var     [MarshalAs(UnmanagedType.LPStr)] //in this case using a pointer to a null-terminated array of ANSI characters.
    lpData: System.String;
  end;

  ConsoleApp = class
  public
    const     WM_COPYDATA: System.Int32 = $4a;//WM_COPYDATA  0x004A
    class method Main(args: array of string);
    [DllImport('user32.dll', EntryPoint := 'FindWindow')]
    class method FindWindow(lpClasName: System.String; lpWindowName: System.String): System.IntPtr; external;
    [DllImport('user32.dll', EntryPoint := 'SendMessage')]
    class method SendMessage(hWnd: System.IntPtr; Msg: System.Int32; wParam: System.Int32; var lParam: CopyDataStruct): System.Int32; external;
  end;


implementation

class method ConsoleApp.Main(args: array of string);
var
 cd   : CopyDataStruct;
 WHnd : IntPtr; 
begin
 cd.dwData := IntPtr(0);//Dummy
 cd.lpData := 'Hello from Delphi Prism - Console Application';//message to send
 cd.cbData := cd.lpData.Length;//set the length of the message
 WHnd      := FindWindow(nil, 'PrismForm');//find the handle for the window of the receiver app
 if (WHnd<>System.IntPtr.Zero) then //check if <> to 0
 begin
  SendMessage(WHnd, WM_COPYDATA, 0, var cd); //Send the message to the app
  Console.WriteLine('Message sent');
 end
 else
 Console.WriteLine('Window not found');
 Console.ReadKey();
end;

end. 

Now the code for the receiver app.

first you must override the WndProc method , to do this you just write something like this.

  MainForm = partial class(System.Windows.Forms.Form) //this is your form
  private
    const     WM_COPYDATA: System.Int32 = $4a; //declare the const for WM_COPYDATA message
  protected
    method Dispose(disposing: Boolean); override;
    method WndProc(var m: Message); override;//override WndProc method to process the messages
  public
    constructor;
  end;

then declare the same structure of the sender app to process the message

  [StructLayout(LayoutKind.Sequential)] 
  CopyDataStruct = public record
  public
    var     dwData: IntPtr;
    var     cbData: System.Int32;
    var     [MarshalAs(UnmanagedType.LPStr)]
    lpData: System.String;
  end;

and finally implement the WndProc method like this

method MainForm.WndProc(var m: Message);
var 
cd: CopyDataStruct;
s : System.String;
begin
  case m.Msg of 
    WM_COPYDATA:  
                begin
                  //the  GetLParam function convert the LParam value an object.
                  //the  typeof function obtains the type of an object
                  cd:= m.GetLParam(typeof(CopyDataStruct)) as CopyDataStruct;
                  s := cd.lpData.Substring(0,cd.cbData);
                  // do your stuff here
                end;
  end;
  inherited WndProc(var m);
end;